//// -------------------------------------------------------------------------
//// File     : DDEdText.dcl
//// Copyright: cad nauseam, 1997-1999.  Shareware, NOT freeware.
////            All rights reserved.
//// Author   : Steve Johnson
//// Purpose  : Dialogue box definition for DDEdText and DDEdOne commands
////            when editing text, dimension, rtext and mtext entities.
//// Notes    : User-modifiable items are indicated with **
//// Version  : 4.0
//// Date     : 18 November 1999
////**************************************************************************
//// User-modified version by Herman Mayfarth, Tekton Construction Services
//// User's version ID : 4.01.tktn02
//// Mod Date : 23 Jan 00
////**************************************************************************
//// Modifications:
//// Date: 23 Jan 00
//// Modification: added attribute
////               fixed_width_font    = true;
////               to "text" edit_box for ease of use at high resolution
////               in WinNT
//// Date: 18 Nov 99
//// Modification : Added 3 rows of 5 user buttons to insert codes for common
////                fractions by 16ths.
//// TEXT         : codes are for tktnxxxx bigfonts. See below for availability.
//// MTEXT        : codes are for text height = 0.75 normal text height
////              : MTEXT fraction codes are for unbarred fractions
////              : (^ in place of /) in accordance with common practice
////              : in U.S. steel fabrication industry. Should you wish to use
////              : vertical barred fractions, substitute / for ^ in applicable
////              : mtext_string attributes, viz: "{\\H0.75x;\\S1/16;}"
//// Modification : Added additional rows of user buttons for special symbols.
////              : All codes are for tktnxxxx bigfonts, which are available
////              : online at http://www.tktn.com as *.shp files. These fonts
////              : all use identical escape codes, and differ only as to the
////              : representation of common fractions. Three fraction styles
////              : are provided: diagonal slash, vertical barred & unbarred.
//// Modification : The cad nauseam standard insert_row_2 is relocated to be
////              : the last row of user-modifiable buttons.
//// Modification : set edit_limit= 320
////**************************************************************************
//// -------------------------------------------------------------------------
/// Turn off error checking
/// --------------------------------------------------------------------------

dcl_settings : default_dcl_settings { audit_level = 0; }


/// --------------------------------------------------------------------------
/// Widget: ddedtext
/// This is the main dialogue box.
/// --------------------------------------------------------------------------

ddedtext : dialog {
  key                   = "title";
  initial_focus         = "text";
  dded_buttons;
  insert_row_2;

// ---------------------------------------------------------------------------
// ** To add extra rows of buttons, add additional lines below, incrementing
//    the integer value, which enumerates the row:
  insert_row_3;
  insert_row_4;
  insert_row_5;
  insert_row_6;
  insert_row_7;
  insert_row_8;
  insert_row_9;
// You can modify the contents of these rows.
// ---------------------------------------------------------------------------

  current_row;
  edit_row;
  spacer;
  full_ok_cancel;
} // end ddedtext


/// --------------------------------------------------------------------------
/// Widget: dded_buttons
/// Row of buttons above text.
/// --------------------------------------------------------------------------

dded_buttons : row {
  alignment             = centered;
  : fixed_button {
    label               = "Flip Case";
    key                 = "case";
  }

// ---------------------------------------------------------------------------
// ** The following 3 buttons can be modified, as described in DDEDTEXT.TXT
  : fixed_button {
    key                 = "insert_1";
    label               = "Degrees";
    mtext_string        = "%%d";
    text_string         = "%%d";
    replace_all         = false;
    at_start            = false;
    is_lisp             = false;
  }
  : fixed_button {
    key                 = "insert_2";
    label               = "Diameter";
    mtext_string        = "%%c";
    text_string         = "%%c";
    replace_all         = false;
    at_start            = false;
    is_lisp             = false;
  }
  : fixed_button {
    key                 = "insert_3";
    label               = "+/-";
    mtext_string        = "%%p";
    text_string         = "%%p";
    replace_all         = false;
    at_start            = false;
    is_lisp             = false;
}
  : fixed_button {
    label               = "User...";
    key                 = "user";
  }
// ---------------------------------------------------------------------------

} // end dded_buttons


/// --------------------------------------------------------------------------
/// Widgets: insert_row_2, insert_row_3 and insert_row_4
/// ** Extra rows of buttons which can be used to provide instant access to
/// user-defined insert strings.  See DDEdText.doc for details of how to
/// change the buttons.
/// --------------------------------------------------------------------------
insert_row_2 : row {
  alignment             = centered;
  : fixed_button {
    key                 = "insert_4";
    label               = "1/16";
    mtext_string        = "{\\H0.75x;\\S1^16;}";
    text_string         = "~1";
  }
  : fixed_button {
    key                 = "insert_5";
    label               = "1/8";
    mtext_string        = "{\\H0.75x;\\S1^8;}";
    text_string         = "~2";
  }
  : fixed_button {
    key                 = "insert_6";
    label               = "3/16";
    mtext_string        = "{\\H0.75x;\\S3^16;}";
    text_string         = "~3";
  }
  : fixed_button {
    key                 = "insert_7";
    label               = "1/4";
    mtext_string        = "{\\H0.75x;\\S1^4;}";
    text_string         = "~4";
  }
  : fixed_button {
    key                 = "insert_8";
    label               = "5/16";
    mtext_string        = "{\\H0.75x;\\S5^16;}";
    text_string         = "~5";
  }
} // end insert_row_2


insert_row_3 : row {
  alignment             = centered;
  : fixed_button {
    key                 = "insert_9";
    label               = "3/8";
    mtext_string        = "{\\H0.75x;\\S3^8;}";
    text_string         = "~6";
  }
  : fixed_button {
    key                 = "insert_10";
    label               = "7/16";
    mtext_string        = "{\\H0.75x;\\S7^16;}";
    text_string         = "~7";
  }
  : fixed_button {
    key                 = "insert_11";
    label               = "1/2";
    mtext_string        = "{\\H0.75x;\\S1^2;}";
    text_string         = "~8";
  }
  : fixed_button {
    key                 = "insert_12";
    label               = "9/16";
    mtext_string        = "{\\H0.75x;\\S9^16;}";
    text_string         = "~9";
  }
  : fixed_button {
    key                 = "insert_13";
    label               = "5/8";
    mtext_string        = "{\\H0.75x;\\S5^8;}";
    text_string         = "~A";
  }
} // end insert_row_3
//** added additional row of 5 fixed_buttons **
insert_row_4 : row {
  alignment             = centered;
  : fixed_button {
    key                 = "insert_14";
    label               = "11/16";
    mtext_string        = "{\\H0.75x;\\S11^16;}";
    text_string         = "~B";
  }
  : fixed_button {
    key                 = "insert_15";
    label               = "3/4";
    mtext_string        = "{\\H0.75x;\\S3^4;}";
    text_string         = "~C";
  }
  : fixed_button {
    key                 = "insert_16";
    label               = "13/16";
    mtext_string        = "{\\H0.75x;\\S13^16;}";
    text_string         = "~D";
  }
  : fixed_button {
    key                 = "insert_17";
    label               = "7/8";
    mtext_string        = "{\\H0.75x;\\S7^8;}";
    text_string         = "~E";
  }
  : fixed_button {
    key                 = "insert_18";
    label               = "15/16";
    mtext_string        = "{\\H0.75x;\\S15^16;}";
    text_string         = "~F";
  }
} // end insert_row_4
//** added additional row of 5 fixed_buttons 11/98
insert_row_5 : row {
  alignment             = centered;
  : fixed_button {
    key                 = "insert_19";
    label               = "PLATE";
    mtext_string        = "~P";
    text_string         = "~P";
  }
  : fixed_button {
    key                 = "insert_20";
    label               = "ANGLE";
    mtext_string        = "~L";
    text_string         = "~L";
  }
  : fixed_button {
    key                 = "insert_21";
    label               = "Ctr. Line";
    mtext_string        = "~c";
    text_string         = "~c";
  }
  : fixed_button {
    key                 = "insert_22";
    label               = "R/L";
    mtext_string        = "~/";
    text_string         = "~/";
  }
  : fixed_button {
    key                 = "insert_23";
    label               = "NS,FS";
    mtext_string        = "~N";
    text_string         = "~N";
  }
} // end insert_row_5
//** added additional row of 5 fixed_buttons 11/98
insert_row_6 : row {
  alignment             = centered;
  : fixed_button {
    key                 = "insert_24";
    label               = "_X_";
    mtext_string        = " X ";
    text_string         = " X ";
  }
  : fixed_button {
    key                 = "insert_25";
    label               = "<>";
    mtext_string        = "<>";
    text_string         = "<>";
  }
  : fixed_button {
    key                 = "insert_26";
    label               = "R";
    mtext_string        = "~r";
    text_string         = "~r";
  }
  : fixed_button {
    key                 = "insert_27";
    label               = "L";
    mtext_string        = "~s";
    text_string         = "~s";
  }
  : fixed_button {
    key                 = "insert_28";
    label               = "TYP";
    mtext_string        = "~T";
    text_string         = "~T";
  }
} // end insert_row_6
//** added additional row of 5 fixed_buttons 11/98
insert_row_7 : row {
  alignment             = centered;
  : fixed_button {
    key                 = "insert_29";
    label               = "U_score";
    mtext_string        = "\\L";
    text_string         = "%%u";
  }
  : fixed_button {
    key                 = "insert_30";
    label               = "BS";
    mtext_string        = "~b";
    text_string         = "~b";
  }
  : fixed_button {
    key                 = "insert_31";
    label               = "GA ";
    mtext_string        = "~G";
    text_string         = "~G";
  }
  : fixed_button {
    key                 = "insert_32";
    label               = "GOL";
    mtext_string        = "~g";
    text_string         = "~g";
  }
  : fixed_button {
    key                 = "insert_33";
    label               = "ONE";
    mtext_string        = "ONE";
    text_string         = "ONE";
    replace_all         = true;
  }
} // end insert_row_7

//** added additional row of 5 fixed_buttons 10/99
insert_row_8 : row {
  alignment             = centered;
  : fixed_button {
    key                 = "insert_34";
    label               = "U_score";
    mtext_string        = "\\l";
    text_string         = "%%u";
  }
  : fixed_button {
    key                 = "insert_35";
    label               = "Dbl. Angle";
    mtext_string        = "~d";
    text_string         = "~d";
  }
  : fixed_button {
    key                 = "insert_36";
    label               = "Inv. Dbl. L ";
    mtext_string        = "~u";
    text_string         = "~u";
  }
  : fixed_button {
    key                 = "insert_37";
    label               = "Ang Sym";
    mtext_string        = "~l";
    text_string         = "~l";
  }
  : fixed_button {
    key                 = "insert_38";
    label               = "Sq. Ft.";
    mtext_string        = "~S";
    text_string         = "~S";
  }
} // end insert_row_8

insert_row_9 : row {
  alignment             = centered;
  : fixed_button {
    key                 = "insert_39";
    label               = "Clear";
    mtext_string        = "";
    text_string         = "";
    replace_all         = true;
    at_start            = false;
    is_lisp             = false;
  }
  : fixed_button {
    key                 = "insert_40";
    label               = "Short date";
    mtext_string        = "(naus_date_today \"M/D/YY\")";
    text_string         = "(naus_date_today \"M/D/YY\")";
    replace_all         = true;
    at_start            = false;
    is_lisp             = true;
  }
  : fixed_button {
    key                 = "insert_41";
    label               = "Long date";
    mtext_string        = "(naus_date_today \"Mmmm D, YYYY\")";
   text_string          = "(naus_date_today \"Mmmm D, YYYY\")";
    replace_all         = false;
    at_start            = false;
    is_lisp             = true;
  }
  : fixed_button {
    key                 = "insert_42";
    label               = "DWG name";
    mtext_string        = "(strcat (getvar \"DWGPREFIX\") (getvar \"DWGNAME\"))";
    text_string         = "(strcat (getvar \"DWGPREFIX\") (getvar \"DWGNAME\"))";
    replace_all         = false;
    at_start            = false;
    is_lisp             = true;
  }
  : fixed_button {
    key                 = "insert_43";
    label               = "Pick file...";
    mtext_string        = "(getfiled \"Pick file\" \"\" \"\" 32)";
    text_string         = "(getfiled \"Pick file\" \"\" \"\" 32)";
    replace_all         = true;
    at_start            = false;
    is_lisp             = true;
  }
} // end insert_row_9


/// --------------------------------------------------------------------------
/// Widget: current_row
/// --------------------------------------------------------------------------

current_row : row {
  : text {
    label               = "Current:";
    width               = 11;
    fixed_width         = true;
  }
  : text {
    key                 = "original";
    alignment           = left;
    width               = 50;
    fixed_width         = false;
  }
} // end current_row


/// --------------------------------------------------------------------------
/// Widget: edit_row
/// --------------------------------------------------------------------------

edit_row : row {
  : text {
    label               = "Edited:";
    width               = 12 ;
    fixed_width         = true;
  }
  : edit_box {
    label               = "";
    key                 = "text";
    edit_width          = 80;
    edit_limit          = 320;
    fixed_width         = false;
    allow_accept        = true;
//added 23 Jan 00 for ease of reading at high-resolution in WinNT
    fixed_width_font    = true;
//---------------------------------------------------------------
  }
} // end edit_row


/// --------------------------------------------------------------------------
/// Widget: full_button
/// --------------------------------------------------------------------------

full_button : fixed_retirement_button {
  label                 = "Full editor...";
  key                   = "full";
} // end full_button


/// --------------------------------------------------------------------------
/// Widget: properties_button
/// --------------------------------------------------------------------------

properties_button : fixed_retirement_button {
  label                 = "Properties...";
  key                   = "properties";
} // end properties_button


/// --------------------------------------------------------------------------
/// Widget: reset_button
/// --------------------------------------------------------------------------

reset_button : fixed_retirement_button {
  label                 = "Reset";
  key                   = "reset";
} // end reset_button


/// --------------------------------------------------------------------------
/// Widget: cancel
/// --------------------------------------------------------------------------

cancel : fixed_retirement_button {
  label                 = "Cancel";
  key                   = "cancel";
  is_cancel             = true;
} // end cancel


/// --------------------------------------------------------------------------
/// Widget: cancel_all
/// --------------------------------------------------------------------------

cancel_all : fixed_retirement_button {
  label                 = "Cancel all";
  key                   = "finish";
} // end cancel_all


/// --------------------------------------------------------------------------
/// Widget: ok
/// --------------------------------------------------------------------------

ok : fixed_retirement_button {
  label                 = "OK";
  key                   = "accept";
  is_default            = true;
} // end ok


/// --------------------------------------------------------------------------
/// Widget: full_ok_cancel
/// --------------------------------------------------------------------------

full_ok_cancel : column {
  : row {
    alignment           = centered;

// ---------------------------------------------------------------------------
// ** Release 12 users may wish to remove the "Full editor..." button.
// To do this, place double slashes // at the start of the next two lines.
    full_button;
// ---------------------------------------------------------------------------

    properties_button;
    reset_button;
    ok;
    cancel;
    cancel_all;
  }
} // end full_ok_cancel


/// --------------------------------------------------------------------------
/// Widget: fixed_button
/// --------------------------------------------------------------------------

fixed_button : button {
// ---------------------------------------------------------------------------
// ** If you are trying to squeeze a lot of insert_N buttons onto a row, then
// reducing the width value below will help.
  width                 = 18;
// ---------------------------------------------------------------------------
  fixed_width           = true;
} // end fixed_button


/// --------------------------------------------------------------------------
/// Widget: fixed_retirement_button
/// --------------------------------------------------------------------------

fixed_retirement_button : retirement_button {
  width                 = 14;
  fixed_width           = true;
} // end fixed_retirement_button


/// --------------------------------------------------------------------------
/// Widget: list_user
/// This is a sub dialogue box used to list the user-defined insert strings.
/// --------------------------------------------------------------------------

list_user : dialog {
  label                 = "User Text to Insert";
  : list_box {
    key                 = "list_box";
    at_start            = false;
    width               = 100;
    height              = 28;
  }
  ok_cancel;
} // end list_user


//// -------------------------------------------------------------------------
//// End DDEDTEXT.DCL
//// -------------------------------------------------------------------------